工具搜索引擎 加入收藏
意见反馈
帮助中心
繁體中文
首页 工具超市 产品信息 资讯中心 工具黄页 站长工具 实用工具 会员管理 联系我们  
广告投放
您当前的位置:工具网站长书库> VBScript教程

VBScript循环语句

使用 VBScript 循环语句

循环用于重复执行一组语句。循环可分三类:

    在条件变为 False 之前重复执行语句。 在条件变为 True 之前重复执行语句。 按照指定的次数重复执行语句。

在 VBScript 中可使用下列循环语句:

    Do...Loop :当 (或直到)条件为 True 时循环。 While...Wend :当条件为 True 时循环。 For...Next :指定循环次数,使用计数器重复运行语句。 For Each...Next :对于集合中的每项或数组中的每个元素,重复执行一组语句。

使用 Do 循环语句

可以使用 Do...Loop 语句多次(次数不定)运行语句块。当条件为 True 时或条件变为 True 之前,重复执行语句块。

当条件为 True 时重复执行语句

While 关键字用于检查 Do...Loop 语句中的条件。有两种方式检查条件:在进入循环之前检查条件(Do While...Loop );或者在循环至少运行完一次之后检查条件(Do...Loop While)。

Do While...Loop 示例:

<script type="text/vbscript">
 Sub ChkFirstWhile()
     Dim counter, myNum
     counter = 0
     myNum = 20
     Do While myNum > 10
         myNum = myNum - 1
         counter = counter + 1
     Loop
     MsgBox "循环重复了 " & counter & " 次。"
 End Sub
Call ChkFirstWhile
</script>

演示示例

Do...Loop While 示例:

<script type="text/vbscript">
 Sub ChkLastWhile()
     Dim counter, myNum
     counter = 0
     myNum = 9
     Do
         myNum = myNum - 1
         counter = counter + 1
     Loop While myNum > 10
     MsgBox "循环重复了 " & counter & " 次。"
 End Sub
 Call ChkLastWhile
</script>

演示示例

重复执行语句直到条件变为 True

Until 关键字用于检查 Do...Loop 语句中的条件。有两种方式检查条件:在进入循环之前检查条件(Do Until...Loop);或者在循环至少运行完一次之后检查条件(Do...Loop Until)。只要条件为 False,就会进行循环。

Do Until...Loop 示例:

<script type="text/vbscript">
 Sub ChkFirstUntil()
     Dim counter, myNum
     counter = 0
     myNum = 20
     Do Until myNum = 10
         myNum = myNum - 1
         counter = counter + 1
     Loop
     MsgBox "循环重复了 " & counter & " 次。"
 End Sub
 Call ChkFirstUntil
</script>

演示示例

Do...Loop Until 示例:

<script type="text/vbscript">
 Sub ChkLastUntil()
     Dim counter, myNum
     counter = 0
     myNum = 1
     Do
         myNum = myNum + 1
         counter = counter + 1
     Loop Until myNum = 10
     MsgBox "循环重复了 " & counter & " 次。"
 End Sub
 Call ChkLastUntil
</script>

演示示例

退出循环

Exit Do 语句用于退出 Do...Loop 循环。因为通常只是在某些特殊情况下要退出循环(例如要避免死循环),所以可在 If...Then...Else 语句的 True 语句块中使用 Exit Do 语句。如果条件为 False,循环将照常运行。

在下面的示例中,myNum 的初始值将导致死循环。If...Then...Else 语句检查此条件,防止出现死循环。

<script type="text/vbscript">
 Sub ExitExample()
     Dim counter, myNum
     counter = 0
     myNum = 9
     Do Until myNum = 10
         myNum = myNum - 1
         counter = counter + 1
         If myNum < 10 Then Exit Do
     Loop
     MsgBox "循环重复了 " & counter & " 次。"
 End Sub
 Call ExitExample
</script>

演示示例

使用 While...Wend 循环语句

While...Wend 语句是为那些熟悉其用法的用户提供的。但是由于 While...Wend 缺少灵活性,所以建议最好使用 Do...Loop 语句。

使用 For...Next 循环语句

For...Next 语句用于将语句块运行指定的次数。在循环中使用计数器变量,该变量的值随每一次循环增加或减少。以下是个简单示例:

<script type="text/vbscript">
  Dim i
  for i = 0 to 10
     document.write("Number " & i & "<br />")
  next
</script>

演示示例

关键字 Step 用于指定计数器变量每次增加或减少的值。在下面的示例中,计数器变量 j 每次加 2。循环结束后,total 的值为 2、4、6、8 和 10 的总和。

<script type="text/vbscript">
 Sub TwosTotal()
     Dim j, total
     For j = 2 To 10 Step 2
         total = total + j
     Next
     MsgBox "总和为 " & total & "。"
 End Sub
 Call TwosTotal
</script>

演示示例

要使计数器变量递减,可将 Step 设为负值。此时计数器变量的终止值必须小于起始值。在下面的示例中,计数器变量 myNum 每次减 2。循环结束后,total 的值为 16、14、12、10、8、6、4 和 2 的总和。

 Sub NewTotal()
     Dim myNum, total
     For myNum = 16 To 2 Step -2
         total = total + myNum
     Next
     MsgBox "总和为 " & total & "。"
 End Sub

Exit For 语句用于在计数器达到其终止值之前退出 For...Next 语句。因为通常只是在某些特殊情况下(例如在发生错误时)要退出循环,所以可以在 If...Then...Else 语句的 True 语句块中使用 Exit For 语句。如果条件为 False,循环将照常运行。

返回上级目录
VBScript
VBScript教程
VBScript简介
VBScript写在哪里
VBScript变量
VBScript运算符
VBScript条件语句
VBScript循环语句
VBScript过程
VBScript代码示例
VBScript入门代码示例